# Project file for QtSizeableDisplay
#
# You can e.g. call 
# cmake <loc> -D QTVERSION_MAJOR=4 
# to force the Qt version to Qt4.

cmake_minimum_required(VERSION 3.0)
project(QtSizeableDisplay)

# Make CMake aware of our FindCVB.cmake module
file(TO_CMAKE_PATH "$ENV{CVB}/cmake" CVB_MODULE_PATH)
set(CMAKE_MODULE_PATH "${CMAKE_MODULE_PATH}" "${CVB_MODULE_PATH}")
find_package(CVB REQUIRED)

# If version not specified try to find default installed one
if(NOT QTVERSION_MAJOR)
  execute_process(COMMAND qmake -v OUTPUT_VARIABLE QTINFO 
                                   RESULT_VARIABLE QMAKE_ERROR)
  if(NOT QMAKE_ERROR STREQUAL 0)
    message(FATAL_ERROR "Could not execute qmake. Ensure QT development package is installed")
  endif()
  string(REGEX MATCH "Qt version [0-9]+\\." QTVERSION_MAJOR "${QTINFO}")
  string(REGEX MATCH "[0-9]+" QTVERSION_MAJOR "${QTVERSION_MAJOR}")
endif()

# Group files for Visual Studio
source_group("Generated Files" REGULAR_EXPRESSION "(moc|qrc).*c..$")
source_group("Resource Files" REGULAR_EXPRESSION ".*/.*rc$")

# Resources and targets for Qt
if(QTVERSION_MAJOR EQUAL 4)
  find_package(Qt${QTVERSION_MAJOR} REQUIRED)
  qt4_add_resources(RESOURCES_RCC QtSizeableDisplay.qrc)
  set(QTTARGETS Qt4::QtGui)
else()
  find_package(Qt5Widgets REQUIRED)
  qt5_add_resources(RESOURCES_RCC QtSizeableDisplay.qrc)
  set(QTTARGETS Qt5::Widgets)
endif()

# Create Qt Window target and link necessary libs
set(CMAKE_AUTOMOC ON)
add_executable(QtSizeableDisplay WIN32
  main.cpp
  mainwidget.hpp
  mainwidget.cpp
  QtSizeableDisplay.rc
  QtSizeableDisplay.qrc
  ${RESOURCES_RCC}
)
target_link_libraries(QtSizeableDisplay
  CVB::CVCDriver
  CVB::CVCUtilities
  ${QTTARGETS}
)

